* This file computes correlations between corresponding variables in R&M data set and one provided by Mark Pitt in 2008, which may or may not match the original
* Correlations reported in R&M Table 1

* odbc load, exec("select * from [Roodman & Morduch HH] where wave in (1,2,3)") dsn(PK) clear
use "Roodman & Morduch HH", clear
keep if pksample & wave<4

foreach var in fbraclv mbraclv fbrdblv mbrdblv fgramlv mgramlv {
	gen double `var'pk = cond(l`var'pk, exp(l`var'pk), 0)
}
gen double fproglvpk = fbraclvpk + fbrdblvpk + fgramlvpk
gen double mproglvpk = mbraclvpk + mbrdblvpk + mgramlvpk
gen double proglvpk = fproglvpk + mproglvpk
scalar C_0 = ln(1)
foreach var in fproglv mproglv proglv {
	gen double l`var'pk = cond(`var'pk, ln(`var'pk), C_0)
}

replace pzwflour=0 if pzwflour==. // needed to match sample sizes. These prices are actually stored as 0 in original data.
replace pzmilk=0 if pzmilk==.
xi i.wave i.village
gen double fasset = fnlasset + flandvalb
gen byte ineligible = !eligible
scalar C_0 = ln(1)   // credit censoring level
quietly {
	foreach var in fproglv mproglv fbraclv mbraclv fbrdblv mbrdblv fgramlv mgramlv proglv {
		gen double l`var' = ln(`var')
		recode l`var' (. = `=C_0')
	}
	replace landaf = .1 if landaf==0 // according to Pitt e-mail, 1/4/08
	replace landbe = .1 if landbef==0
	gen double llandaf = ln(landaft)
	gen double llandbef = ln(landbef)
	gen double lpcnsexp = ln(pcnsexp)
	gen byte crcensored = progid<4 & proglv==0
}

* correlations between corresponding variables in two data sets
foreach var in lpcnsexp spsislndd spbrolndd spparlndd hdsislndd hdbrolndd hdparlndd llandbef edhead sexhead agehead afedhigh amedhigh amadultd afadultd scohead ///
	lfbraclv lmbraclv lfbrdblv lmbrdblv lfgramlv lmgramlv lfproglv lmproglv crcensored {
	corr `var' `var'pk
}
* correlations for education variables taking into account that PK set years of education=0 for current student
corr afedhighns afedhighpk
corr amedhighns amedhighpk
corr q choicepk