// Download World Bank Poverty Data
	pip, povline(2.15 3.5 4 5 10) fillgaps clear

// Create FCAS Dummy Variable
	// (Note: this is the World Bank FY24 List of Fragile and Conflict-affected Situations available at: 
	// https://thedocs.worldbank.org/en/doc/608a53dd83f21ef6712b5dfef050b00b-0090082023/original/FCSListFY24-final.pdf)
	gen fcas = 0
	local country_codes "AFG BFA CMR CAF COD ETH IRQ MLI MOZ MMR NER NGA SOM SSD SDN SYR UKR PSE YEM BDI TCD COM COG ERI GNB HTI KIR XKX LBN LBY MHL FSM PNG STP SLB TLS TUV VEN ZWE"
	foreach code in `country_codes' {
		replace fcas = 1 if country_code == "`code'"
	}

// Create Poverty Count	
	gen 	popinpov=population*headcount
	replace popinpov=popinpov/1000000

// Drop incomplete data	
	drop if year>2019

// Create trends graph
	format poverty_line %12.0g
	set graph off
	foreach n in 2.15 3.5 5 10{
		preserve
			keep if poverty_line==`n'
			collapse (sum) popinpov, by(fcas year)
			local name=floor(`n') 
			tw (line popinpov year if fcas==0)(line popinpov year if fcas==1), legend(label(1 "Other")label(2 "FCAS")pos(3)) ///
				subtitle("Pop in Poverty (million)",pos(11)span)title("$`n' per day Poverty Line")ytitle("")name("l`name'",replace)
			table year fcas, c(sum popinpov)
		restore
		}
	set graph on

	graph combine l2 l3 l5 l10

	
// Create bar graph
	preserve
		keep if year==2019
		collapse (sum) popinpov, by(fcas poverty_line)
		reshape wide popinpov, i(poverty_line)j(fcas)
		gen share=popinpov1/(popinpov1+popinpov0)*100
		graph hbar share, over(poverty_line) subtitle("$ per day poverty line",pos(11)span)ytitle("Share of the poor in fragile states")blabel(total,format(%9.0fc))
	restore

		preserve
			keep if poverty_line==2.15
			collapse (sum) popinpov, by(fcas year)
			local name=floor(2.15)
			gen forecast=popinpov if year>2019
			replace popinpov=. if year>2019
			tw (line popinpov year if fcas==0)(line popinpov year if fcas==1) ///
     		   (line forecast year if fcas==0)(line forecast year if fcas==1) ///
			, legend(label(1 "Other")label(2 "FCAS")pos(3)) ///
				subtitle("Pop in Poverty (million)",pos(11)span)title("$`n' per day Poverty Line")ytitle("")name("l`name'",replace)
		restore

// Out of School Children		
	wbopendata, indicator(SE.PRM.UNER) long clear
	drop if inlist(regionname,"Aggregates","")
	drop if year<1980
	// Create FCAS Dummy Variable
		gen fcas = 0
		local country_codes "AFG BFA CMR CAF COD ETH IRQ MLI MOZ MMR NER NGA SOM SSD SDN SYR UKR PSE YEM BDI TCD COM COG ERI GNB HTI KIR XKX LBN LBY MHL FSM PNG STP SLB TLS TUV VEN ZWE"
		foreach code in `country_codes' {
			replace fcas = 1 if countrycode == "`code'"
		}

	collapse (sum) se_prm_uner, by(fcas year)

	replace se_prm_uner=se_prm_uner/1000000

	tw (line se_prm_uner year if fcas==0)(line se_prm_uner year if fcas==1), legend(label(1 "Other")label(2 "FCAS")pos(4)) ///
					subtitle("Million",pos(11)span)title("Primary-age children out of school")ytitle("")name(outofschool,replace)

// Child Mortality				
	wbopendata, indicator(SP.DYN.IMRT.IN;SP.DYN.CBRT.IN;SP.POP.TOTL;SH.DYN.MORT) long clear
	drop if inlist(regionname,"Aggregates","")
	gen thousandpeople=sp_pop_totl/1000
	gen births=sp_dyn_cbrt_in*thousandpeople
	gen thousandbirths=births/1000
	gen infantdeaths=sp_dyn_imrt_in*thousandbirths
	gen childdeaths=sh_dyn_mort*thousandbirths

	// Create FCAS Dummy Variable
		gen fcas = 0
		local country_codes "AFG BFA CMR CAF COD ETH IRQ MLI MOZ MMR NER NGA SOM SSD SDN SYR UKR PSE YEM BDI TCD COM COG ERI GNB HTI KIR XKX LBN LBY MHL FSM PNG STP SLB TLS TUV VEN ZWE"
		foreach code in `country_codes' {
			replace fcas = 1 if countrycode == "`code'"
		}

	collapse (sum) infantdeaths childdeaths, by(fcas year)
	replace infantdeaths=infantdeaths/1000000
	replace childdeaths=childdeaths/1000000
	drop if year<1980 | year==2022
	tw (line infantdeaths year if fcas==0)(line infantdeaths year if fcas==1), legend(label(1 "Other")label(2 "FCAS")pos(4)) ///
					subtitle("Million",pos(11)span)title("Children dying before age 1")ytitle("") ///
					ylabel(0(1)8)name(u1mort,replace)
	tw (line childdeaths year if fcas==0)(line childdeaths year if fcas==1), legend(label(1 "Other")label(2 "FCAS")pos(4)) ///
					subtitle("Million",pos(11)span)title("Children dying before age 5")ytitle("") ///
					ylabel(0(1)12)name(u5mort,replace)

// Stunting					
	import delimited "/Users/leecrawfurd/Library/CloudStorage/Dropbox-Personal/Downloads/under-5-population.csv", delimiter(comma) clear 
	// Note: This data downloaded from Our World is Data at: https://ourworldindata.org/grapher/under-5-population
	drop if code==""
	ren code countrycode
	tempfile pop
	save `pop'
	wbopendata, indicator(SH.STA.STNT.ME.ZS) long clear
	mmerge countrycode year using `pop'
	keep if _merge==3

	gen stunted=(sh_sta_stnt_me_zs/100)*populationbybroadagegroupsexalla

	// Create FCAS Dummy Variable
		gen fcas = 0
		local country_codes "AFG BFA CMR CAF COD ETH IRQ MLI MOZ MMR NER NGA SOM SSD SDN SYR UKR PSE YEM BDI TCD COM COG ERI GNB HTI KIR XKX LBN LBY MHL FSM PNG STP SLB TLS TUV VEN ZWE"
		foreach code in `country_codes' {
			replace fcas = 1 if countrycode == "`code'"
		}

	collapse (sum) stunted, by(fcas year)
	replace stunted=stunted/1000000
	drop if year<2000 | year>2021
	tw (line stunted year if fcas==0)(line stunted year if fcas==1), legend(label(1 "Other")label(2 "FCAS")pos(3)rowgap(10)) ///
					subtitle("Million",pos(11)span)title("Children stunted")ytitle("") ///
					ylabel(0(20)160)name(stunted,replace)

// Combined graphs					
	graph combine outofschool stunted u1mort u5mort